because no one else should have to listen to those horrid noises

[zwol]

Suppose you need a ba-da continuum. You go and look for one. You find all kinds of papers that say they used one, and you find instructions on how to synthesize one with Praat. Instructions from Praat's very own manual, even.

Do not follow those instructions. You will not get a ba-da continuum. You will get horrible, horrible squawking noises that bear no resemblance to ba, da, or anything in between.

This is what you do instead: You download the very nice ba-pa continuum from the University of Nebraska speech lab. You extract the first file, bp00-11.wav, which is a sensible-sounding ba. You then run the Praat script which is behind the lj-cut, having first modified it to put the appropriate absolute paths where I have $SOURCE and $DESTINATION.

Create Sound from formula... ba Mono 0 0.05 11025 0
Read from file... $SOURCE/bp00-11.wav
Edit
editor Sound bp00-11
	Select... 0 0.17
	Copy selection to Sound clipboard
	Close
endeditor
select Sound ba
Edit
editor Sound ba
	Paste after selection
	Close
endeditor
select Sound bp00-11
Remove

select Sound ba
To Formant (burg)... 0 5 5000 0.025 50
select Sound ba
To LPC (burg)... 16 0.025 0.005 50
plus Sound ba
Filter (inverse)
Rename... ba_source

select Sound ba
plus LPC ba
Remove

for i from 0 to 10
   select Formant ba
   Copy... bd'i'
   Formula (frequencies)...
      ... if (row = 2 or row = 3) and col < 16 then 
      ...   self + (1-sqrt(col/16)) * 100*i 
      ... else self endif
   plus Sound ba_source
   Filter
   if i < 10
      Write to AIFF file... $DESTINATION/bd0'i'.aiff
   else
      Write to AIFF file... $DESTINATION/bd'i'.aiff
   endif
   plus Formant bd'i'
   Remove
endfor

select Sound ba_source
plus Formant ba
Remove

I am not 100% happy with the synthetic formant-#2 curve that this uses, but it sounds a hell of a lot more like da than the aforementioned squawking noises.

[EDIT 27 Apr 2007: It sounds even more like da if you have it bend both formant #2 and formant #3. Script has been adjusted.]

Comments

:.(

[bakhshizadeh.livejournal.com]

the links are dead.
what can i do?
it was like the one last hope

Re: :.(

[zwol.livejournal.com]

Oh dear, they are. Which file did you need? I might have the ba-pa continuum in my old backups, but not any of the others, I'm afraid.

: )

[bakhshizadeh.livejournal.com]

thanks for your reply
the ba-pa will do just fine
please find them for me
thanks again

Re: : )

[zwol.livejournal.com]

I found them, but I only have them in an awkward format: old-fashioned Macintosh SoundEdit 16 files. If you're using old Psyscope (not Psyscope X) this is exactly what you want; if you're using anything else you will need a conversion program. I do not know where to find one.

Because of that, and also because I'm not sure whether the University of Nebraska took those sound files offline on purpose, I do not want to put the archive back on the web. May I email it to you? It's an 80KB zipfile. There's no contact information in your profile. You can email me at zackw at panix dot com if you would prefer not to reply with your email address.

Re: : )

[bakhshizadeh.livejournal.com]

thanks, i will find a conversion program
this is my email address:
lilyofthevalleyishere (at) yahoo (dot) com

thanks again